**电工电子实验中心**

**实验报告**

课程名称： 微机原理与接口技术实验

实验名称： 8255 并口控制器

姓名： 李应飞 学号: 161610338

评定成绩： 审阅教师： 卓然

实验时间： 2018.11.27

南京航空航天大学

# 实验目的要求

1. 掌握 8255 的工作方式及应用编程。
2. 学习键盘扫描的原理及电路接法。
3. 掌握利用 8255 实现按键扫描及数码管显示方法。

# 实验任务

用 8255 实现键盘扫描与显示功能,当小键盘有键按下时，键值在数码管最右位的位置上显示, 数码管上显示最新六位键值内容,当主键盘有键按下时,返回系统。

# 实验代码（写出自己补全的代码，包含适当注释）

;键盘扫描及数码管显示实验

IOY0 EQU 0E000H ;片选IOY0对应的端口始地址

PA55 EQU IOY0+00H\*4 ;8255的A口地址

PB55 EQU IOY0+01H\*4 ;8255的B口地址

PC55 EQU IOY0+02H\*4 ;8255的C口地址

PCTL EQU IOY0+03H\*4 ;8255的控制寄存器地址

DATA SEGMENT

BUFF DB 6 DUP (10H)

TABLE1 DB 11H,21H,41H,81H,12H,22H,42H,82H ;取反后的键盘扫描码

DB 14H,24H,44H,84H,18H,28H,48H,88H

DCTBL DB 3Fh,06h,5Bh,4Fh,66h,6Dh,7Dh,07h,7Fh,6Fh ;数码管的段码表

DB 77h,7Ch,39h,5Eh,79h,71h,00H

MES DB 'Press any key on the small keyboard!',0DH,0AH

DB 'Press key to display on the led!',0dh,0ah,'$'

MESS DB 'Press main keyboard any key to exit! ',0DH,0AH,0DH,0AH,'$'

KEYC DB ?

KEY DB ?

DATA ENDS

STAC SEGMENT PARA STACK

DB 256 DUP(?)

STAC ENDS

CODE SEGMENT

ASSUME CS:CODE,DS:DATA,SS:STAC

START: MOV AX, DATA

MOV DS, AX

MOV DX,OFFSET MES

MOV AH, 9 ;显示MES

INT 21H

MOV DX,OFFSET MESS

MOV AH, 9 ; 显示MESS

INT 21H

LOP1: CALL TESTKEY

CALL DISP

MOV DL, 0FFH

MOV AH, 6

INT 21H

JZ LOP1

QUIT: MOV AX, 4C00H

INT 21H

TESTKEY PROC

KEY0: MOV AL, 81H

MOV DX, PCTL ;8255控制字,PC0-3入,PC4-7出

OUT DX,AL

MOV AL, 00

MOV DX, PC55 ; C 口输出0

OUT DX,AL

IN AL, DX

AND AL, 0FH ;读入行值,屏蔽列值后保存

MOV KEYC,AL

KEY1: MOV AL, 88H

MOV DX, PCTL ; 8255控制字,PC0-3出,PC4-7入

OUT DX,AL

MOV AL, 00

MOV DX, PC55 ; C 口输出0

OUT DX,AL

IN AL, DX

AND AL, 0F0H ; 读入列值,屏蔽行值后合并取反

OR AL, KEYC

NOT AL

CMP AL,0 ;无键按下退出子程序

JZ KEYEND

MOV SI, OFFSET TABLE1

MOV CX, 16

MOV DL, 00H

KEY2: CMP AL, [SI]

JZ KEY3

INC SI ;查找按键的值

INC DL

DEC CX

JZ KEYEND

JMP KEY2

KEY3: MOV KEY, DL

MOV SI, OFFSET BUFF+1

MOV DI, OFFSET BUFF

MOV CX, 5

KEY4: MOV AL, [SI]

MOV [DI],AL

INC SI ;显示缓冲区内容向前移一位

INC DI

LOOP KEY4

MOV AL, KEY ;当前键值存入BUF[5]单元

MOV [DI],AL

MOV AL, 88H

MOV DX, PCTL ; 8255控制字,PC0-3出,PC4-7入

OUT DX,AL

KEY5: MOV AL, 00

MOV DX, PC55

OUT DX,AL

IN AL, DX ;判断按键是否释放

AND AL, 0F0H

CMP AL,0F0H

JNZ KEY5

KEYEND: RET

TESTKEY ENDP

DISP PROC

PUSH DS

PUSH AX

MOV CL, 1

MOV SI, OFFSET BUFF

DIS2: MOV AL, [SI]

LEA BX, DCTBL

XLAT ;输出段码

MOV DX, PB55

OUT DX,AL

MOV DX, PA55

MOV AL, CL ;输出位码

NOT AL

OUT DX,AL

CALL DELAY

INC SI ;段码地址+1

ROL CL, 1 ;位码向左移1位

CMP CL, 40H ; 位码是最后位吗?

JNZ DIS2 ;不是最后位,转DIS2

POP AX ;是最后位,返回

POP DS

RET

DISP ENDP

DELAY PROC NEAR

PUSH CX

MOV BX,30H

DEL1: MOV CX, 0FFFFH

LOOP $

DEC BX ;延时子程序

JNZ DEL1

POP CX


RET



DELAY ENDP


CODE ENDS

END START

# 简要的电原理框图和程序流程图







# 实验结果

当小键盘有键按下时，键值在数码管最右位的位置上显示, 数码管上显示最新六位键值内容,当主键盘有键按下时,返回系统。

# 心得体会及建议

本实验让我掌握 8255 的工作方式及应用编程和键盘扫描的原理及电路接法，以及掌握利用 8255 实现按键扫描及数码管显示方法。

8255 可编程接口芯片是 Intel 公司生产的通用并行 I/O 接口芯片，它具有 A、B、C 三个并行接口，用+5V 单电源供电，能在以下三种方式下工作：

方式 0--基本输入/出方式。方式 1--选通输入/出方式。方式 2--双向选通工作方式。

键盘是由 4 行×4 列共 16 个按键组成, 其中 PC0～PC3 作为行选择信号 Y1～ Y4,PC4～PC7 作为列扫描信号 X1～X4。在键盘扫描中,常用的方法有逐行扫描和行反转法两种,本实验采用行反转法。 在软件设计上要注意消除按键抖动的处理以及数码管显示的刷新。

数码管显示器是由 6 位共阴的 7 段数码管组成,在电路中它也接成扫描电路方式，6 位共阴的 7 段数码共用段码 A～G、Dp,当位码 L1～L6 某位 0 为时,则该位数码管点亮,显示相应的字符。要在六位数码管上显示不同的内容,需一定频率循环地往六位数码管上输送段码与位码,在因此这种显示方式称为动态显示方式。